yt-dlpを使い始めた - PC関連のチラ裏

何か変化があったかはわかりませんが、youtube-dl.exeやその他古そうなyoutubeからDLするソフトが使えなくなってしまったので、yt-dlpでYoutube動画を落とすバッチを作りました。
主に某TLなぞりゲーム用。もちろん自分用。
ffmpeg,ffprobeをyt-dlpと同じディレクトリに投入。シンボリックリンクにしたけど。

@echo off

cd path\to\yt-dlp
SET yt-dlp=path\to\yt-dlp\yt-dlp.exe


echo "URLを入力"
SET /p URL=


echo 動画は大容量が見込まれる？大きいなら'y'を入力。
echo 　y:
echo 　other:
SET /p LARGE=
if "%LARGE%" == "y" (
	SET output=large\directory
) else (
	SET output=small\directory
)


echo フォーマットを選択したい？
echo 　y:フォーマットを選択する
echo 　b:avc+opusで最高画質 (bv[ext=mp4]+ba[ext=webm])
echo 　other:videoのみ(優先度:298→136→135→134)
SET /p SELECT=


if "%SELECT%" == "y" (
	goto FORMAT-SELECT
) else if "%SELECT%" == "b" (
	goto FORMAT-BEST
) else (
	goto FORMAT-VIDEO-ONLY-AUTO
)


:FORMAT-SELECT

	%yt-dlp% -F %URL%
	echo フォーマット番号を入力。例:298 bv+ba
	SET /p vformat=
	%yt-dlp% -o "%output%\%%(upload_date)s_%%(title)s_%%(id)s.%%(ext)s" -i -f %vformat% --merge-output-format mp4 --write-description --embed-thumbnail %URL%

	goto EXIT





:FORMAT-BEST

	%yt-dlp% -F %URL%
	echo FORMAT-BEST
	%yt-dlp% -o "%output%\%%(upload_date)s_%%(title)s_%%(id)s.%%(ext)s" -i -f "bv[ext=mp4]+ba[ext=webm]" --merge-output-format mp4 --write-description --embed-thumbnail %URL%

	goto EXIT





:FORMAT-VIDEO-ONLY-AUTO

	%yt-dlp% -F %URL%
	echo FORMAT-VIDEO-ONLY-AUTO
	%yt-dlp% -o "%output%\%%(upload_date)s_%%(title)s_%%(id)s.%%(ext)s" -i -f 298/136/135/134 --write-description --embed-thumbnail %URL%

	goto EXIT





rem  --embed-thumbnailを付けるとサムネ画像入れられる(けどmuxの容量が必要)

:EXIT

pause

クッキー使ってログインする方法までは調べてない・・そこまで使いたくなってない。

参考